Save items from pvp theft

int minimum_value = 1000; // Closet everything stealable worth more than this; 0 = closet everything stealable.
boolean verbose = true; // false = Only print the items that gonna be or woulda been closeted.


void main(string show_or_go)
{

    boolean go = (show_or_go.to_lower_case() == "go"); // Anything other than "go" = just show what woulda happened.
    if (minimum_value < 0) abort ("A minimum_value less than zero makes no sense at all.");
    int count_cheap, count_closet, count_total, count_unstealable;
    int [item] inv = get_inventory();
    boolean [item] pvp_unimportant = $items[tenderizing hammer, dramatic range, Queue Du Coq cocktailcrafting kit];
    boolean is_stealable(item it) { return is_tradeable(it) && autosell_price(it) > 0; }
    foreach it, qty in inv {
        int price = -1;
        if (is_stealable(it) && !(pvp_unimportant contains it)) price = historical_price(it);
        if (price < 0) {
            count_unstealable += 1;
            if (verbose) print_html("<span color=\"green\">Not closeting " + qty + " " + (qty == 1 ? to_string(it) + ", it's" : to_plural(it)  + ", they're") + " unstealable.</span>");
        } else if (price >= minimum_value) {
            count_closet += 1;
            print_html("<span color=\"teal\">" + (go ? "Gonna closet " : "Woulda closeted ") + qty + " " + (qty == 1 ? to_string(it) : to_plural(it)) + ".</span>");
            if (go) put_closet(qty, it);
        } else if (price < minimum_value) {
            count_cheap += 1;
            if (verbose) print_html("<span color=\"red\">Not worth closeting " + qty + " " + (qty == 1 ? to_string(it) : to_plural(it)) + ".</span>");
        }
    }
    count_total = count_closet + count_cheap + count_unstealable;
    if (count_closet > 0) print("+ " + count_closet + (go ? "" : " woulda been") + " closeted", "teal");
    if (count_cheap > 0) print("+ " + count_cheap + " worth less than " + minimum_value + " meat", "red");
    if (count_unstealable > 0) print("+ " + count_unstealable + " unstealable", "green");
    if (count_total > 0) print(" = " +  count_total + " of " + count(inv) + " items accounted for.");
    print_html("<b>Done<a href=\"http://kolmafia.us/showthread.php?10059\">!</a></b>");
}

[LEFT][COLOR=#333333]boolean [item] pvp_unimportant = $items[tenderizing hammer, dramatic range, Queue Du Coq cocktailcrafting kit, tiny plastic bitchin' meatcar];[/COLOR][/LEFT]

boolean is_stealable(item it) { return is_tradeable(it) && autosell_price(it) > 0; }

boolean is_pvpable( item thing )
{
	return thing == $item[amulet of yendor] || ( thing.tradeable && thing.discardable && !thing.gift && !thing.quest );
}

boolean is_stealable(item it) { return it.tradeable && it.discardable && !it.gift; }

# pvp_closet_put.ash

# These items only are okay for being picked.
boolean [item] whitelist;

# Food
whitelist[$item[bowl of cottage cheese]]            = true;
whitelist[$item[toast]]                             = true;

# Booze
whitelist[$item[Imp Ale]]                           = true;

# Misc
whitelist[$item[Doc Galaktik's Pungent Unguent]]    = true;

# Hats
whitelist[$item[disco mask]]                        = true;
whitelist[$item[helmet turtle]]                     = true;
whitelist[$item[Hollandaise helmet]]                = true;
whitelist[$item[mariachi hat]]                      = true;
whitelist[$item[ravioli hat]]                       = true;
whitelist[$item[seal-skull helmet]]                 = true;

# Melee
whitelist[$item[pasta spoon]]                       = true;
whitelist[$item[saucepan]]                          = true;
whitelist[$item[seal-clubbing club]]                = true;
whitelist[$item[turtle totem]]                      = true;

# Ranged
whitelist[$item[disco ball]]                        = true;
whitelist[$item[stolen accordion]]                  = true;

# Pants
whitelist[$item[old sweatpants]]                    = true;

# Accessories
whitelist[$item[dirty hobo gloves]]                 = true;

# Misc items
whitelist[$item[cog]]                               = true;
whitelist[$item[spring]]                            = true;
whitelist[$item[sprocket]]                          = true;
whitelist[$item[wad of dough]]                      = true;

# (Mostly) Potions
whitelist[$item[glittery mascara]]                  = true;
whitelist[$item[hair spray]]                        = true;

# (Mostly) Combat Items
whitelist[$item[Knob Goblin firecracker]]           = true;


# The following methods are taken from
# http://kolmafia.us/showthread.php?10059-Save-items-from-pvp-theft
# and a little bit changed to whitelist the stealable items.
# Many thanks to lostcalpolydude for his/her work!

boolean is_pvpable(item it) {
    return it.tradeable && it.discardable && !it.gift && !it.quest;
}

void main() {
    int[item] inventory = get_inventory();

    # batch used to minimize server hits.
    batch_open();
    foreach it in inventory {
        if (is_pvpable(it)) {
            if (whitelist contains it) {
                print_html("whitelisted: " + item_amount(it) + " " + it);
            }
            else {
                print_html("pvpable, to closet: " + item_amount(it) + " " + it);
                put_closet(item_amount(it), it);
            }
        }
    }
    batch_close();
}